// look info //
section skininfo
string name "fooAMP Ultra Expanded"
string author "tk32"
string date "Dec-04-2003"
double version 2.0 // beta
string description "work in progress - please email any suggestions"
string URL "fooamp.metalwings.org"

// presets //
section presets


// custom colours //
section color
list invisible int { 0 0 0 0 }
list null color.invisible
list black int { 255 0 0 0 } 
list white int { 255 255 255 255 }
list gray int { 255 110 110 110 }
list midgray int { 255 150 150 150 }
list lightgray int { 255 200 200 200 }
list offwhite int { 255 225 225 225 }
list alttext int { 255 110 150 110 }
list volume color.alttext


// globals //
section globals
int show show.Always
list contextmenu string { "Context Menu"  "Always On Top|command.look_aot" "Swap Looks|command.look_swap" "|"   "Preferences|command.look_prefs" "|" "Exit|command.foobar2000_exit" }
int trimming trimming.EllipsisCharacter
int textflags textflags.NoWrap
string fontname "Arial Black"
string tooltip ""
int texthint 4
int fontsize 7
int fontstyle 0
list fontcolor color.white
int halign align.near
int valign align.center

// window //
section window
bool titlebar false
bool showtooltips true
int alphablend 255
list tooltipcolor color.white

// background //
section background
string filename "fooAMP_ultra_expand.png"
int width 275
int height 200
int layer0 0 // Background
int layer1 1 // Normal
int layer2 1 // Rollover
int layer3 2 // Pressed
int layer4 2 // PressedRollover
int layer5 3 // Toggled
int layer6 3 // ToggledRollover
int layer7 2 // ToggledPressed
int layer8 3 // ToggledPressedRollover

// common sections //
section button
int y 47
int width 23
int height 19

section menu
int y 3
int height 9

section metaShort
string fontname "arial black"
int fontsize 6
bool textonly true
int x 29
int width 213
string trNum "$num(%tracknumber%,2)."
string plNum "$num(%_playlist_number%,2)."

section metaExtend
int fontsize 8
bool textonly true
list fillcolor int { 190 30 50 80 }
list fillcolor2 color.invisible
int x 6
int width 261
int height 12

string plNum "$num(%_playlist_number%,3)."
string trNum "$num(%tracknumber%,3)."
string fnLength "$len(%_filename%)"
string seperator "$if($strstr(%_filename%,' - '),' - ','-')"
string fileName "$trim($replace($replace(%_filename%,_, ,--,-),%metaExtend._seperator%,-))"
string firstSep "$strchr(%metaExtend._fileName%,-)"
string midSep "$add($strchr($substr(%metaExtend._fileName%,$add(%metaExtend._firstSep%,1),100),-),%metaExtend._firstSep%)"
string lastSep "$strrchr(%metaExtend._fileName%,-)"
string neatDir "$replace($replace($directory(%_path%,1),_, ),-, - )"
string spacer "$ifgreater(%user18._istoggled%,0,         ,)"

string fNum "$ifgreater(%metaExtend._firstSep%,4,,
$substr(%metaExtend._fileName%,1,
$sub(%metaExtend._firstSep%,1)))"

string fArtist "$ifgreater(%metaExtend._firstSep%,4,
$substr(%metaExtend._fileName%,1,$sub(%metaExtend._firstSep%,1)),
$substr(%metaExtend._fileName%,$add(%metaExtend._firstSep%,1),$sub(%metaExtend._midSep%,1)))"

string fTitle "$ifgreater(%metaExtend._firstSep%,4,
$substr(%metaExtend._fileName%,$add(%metaExtend._firstSep%,1),100),
$substr(%metaExtend._fileName%,$add(%metaExtend._midSep%,1),100))"


section user16
string fspec "$if($or($or($strcmp(%title8._isrollover%,1),$strcmp(%title9._isrollover%,1)),$or($strcmp(%title16._isrollover%,1),$strcmp(%title17._isrollover%,1))),%metaExtend._fileName%,)"
list fontcolor int { 255 255 255 0 }
bool textonly true
// bool scroll true
int x 28
int y 147
int width 235
int height 15


section placeHolder
bool textonly true
int halign align.far
int valign align.center
int fontsize 6
int x 6
int width 35

section id3
string neatAlbum "$trim($caps2($replace($if2(%album%,%metaExtend._neatDir%),_, ))) ['('%date%')']"
string neatArtist "$trim($caps2($replace($if2(%artist%,$ifgreater(%user19._istoggled%,0,%metaExtend._fArtist%,)),_, )))"
string neatTitle "$trim($caps2($replace($if2(%title%,$ifgreater(%user19._istoggled%,0,%metaExtend._fTitle%,)),_, )))"

section tech
bool textonly true
string bitsize "$len(%__bitrate%)"
string rate "$div(%__samplerate%,1000)"
string kbpkhz "kbps     khz"
string fileType "$upper($ext(%_filename_ext%)) [$lower('('%__extrainfo%')')]"
string stereo "$select(%__channels%,MONO,STEREO,%__channels%ch)"


// short section //

section prev 
int x 7
int width 25
string include button

section play
int show show.IsStopped
int x 30
string include button

section user0
int show show.IsPlaying
int command command.playback_pause
int command_rbu command.playback_play
string include play

section stop
int x 53
string include button

section next
int command_rbu command.playback_next_rand
int x 75
int width 25
string include button

//

section Togglefb2k // 'PL' button
int toggle 0
int x 246
int y 18
int height 11
string include button

section user1  // 'CFG' button
int command command.foobar2000_config
int x 246
int y 31
int height 11
string include button

//

section user2 // main menu
list menu string { "main" "|" "fooAMP Ultra v2.0" "|" "Always On Top|command.look_aot" "Swap Looks|command.look_swap" { "Looks" } "|" "Preferences|command.look_prefs" "|" "Close Skin|command.look_close" "Exit|command.foobar2000_exit" }
int x 5
int width 14
string include menu

section user3 // file menu
list menu string { "file" "|" "Open...|command.playlist_addfiles" "|" "Show Playlist|command.window_bring_to_front" { "Playlists" }  "|" "Exit|command.foobar2000_exit" "|" } 
int x 19
int width 18
string include menu

section user4 // playback menu
list menu string { "playback"  "|" { "Order" "Default|command.playback_default" "Random|command.playback_shuffle" "Repeat|command.playback_repeat" "Repeat One|command.playback_repeat_one"} "|" "Play|command.playback_play" "Pause|command.playback_pause" "Stop|command.playback_stop"  "Previous|command.playback_prev" "Next|command.playback_next" "Random|command.playback_rand" "|"  }
int x 39
int width 39
string include menu

section user5 // title bar
bool layers false
int show show.lookactive
int command_lbd command.look_move
int command_rbu command.look_swap
int x 80
int y 1
int width 130
int height 12

section close // close look
int x 254
int width 10
string include menu

section user6 // quit fb2k
int command command.foobar2000_exit
int x 264
int width 10
string include menu

section user7 // shrink / expand button
int command command.look_swap
int x 248
int y 49
int width 21
int height 15
string include button

//

section title20 // tracknum
string fontname "tahoma"
int fontsize 9
int fontstyle 1
string fspec  "$if(%tracknumber%,%metaShort._trNum%,%metaShort._plNum%)"
int x 7
int y 17
int width 24
int height 16
string include metaShort

section title1 // artist/filename
string fspec "$ifgreater(%_volumechange%,0,Gain: %_volumedb%,$upper($if(%artist%,%artist%,%_filename_ext%)))"
int y 14
int height 12
string include metaShort

section title2 // title/path
string fspec  "$ifgreater(%_volumechange%,0,,$upper($if(%artist%,$if2( - %title%,untitled),/$directory(%_path%,1)/)))"
int y 23
string include title1

section title19 // gain bar
bool textonly true
int fontsize 5
int fontstyle 1
int texthint 0
list fillcolor color.invisible
list fontcolor color.invisible
list fontcolor2 color.alttext
string fspec  "$ifgreater(%_volumechange%,0,$repeat(|,$mul($add(%_volume%,50),2)),)"
string include title2

//

section user9 // always on top
int toggle 1
int command command.look_aot
string tooltip "Switch $ifgreater(%_istoggled%,0,Off,On) Always-on-Top"
int x 196
int y 38
int width 12
int height 13
string include button

// progress & volume controls //

section progress
int x 21
int y 37
int width 156
int height 8

section progressgrip
bool nolayers true
int y progress.y
int width 29
int height 9
int srcx 275
int srcy 48

section volumelevel
int command_rbu command.volume_mute_toggle
int mindB -40
list fillcolor2 color.volume
int x 195
int y 57
int width 35
int height 4

section volumegrip
bool nolayers true
int command_rbu command.volume_mute_toggle
int y 54
int width 14
int height 11
int srcx 275
int srcy 0

//

section indicator
int x 228
int y 41
int srcx 291
int srcy 23
int width 11
int height 9

section user10
int show show.isplaying
string include indicator

section user11
int show show.ispaused
int srcy 36
string include indicator

section user12
int show show.isstopped
int srcx 276
string include indicator


// expanded section //

// top line //

section title3 // tracknum / playnum
int toggle 0
int fontsize 16
list fontcolor color.gray
string fspec  "$ifgreater(%_istoggled%,0,%metaExtend._plNum%,$if(%tracknumber%,%metaExtend._trNum%,%metaExtend._plNum%))"
int x 3
int y 72
int width 61
int height 18

section title4 // num type
string fspec  "$ifgreater(%title3._istoggled%,0,playlist,$if(%tracknumber%,track,playlist))"
int fontsize 7
int x 7
int y 88
int width 50
int height 8
string include title3

section title5 // show meta/file heading
int fontsize 8
list fontcolor color.lightgray
string fspec "$ifgreater(%user14._istoggled%,0,$if(%artist%,:: file data ::,:: no metadata ::),$if(%artist%,:: track metadata ::,:: no metadata ::))"
int halign align.center
int x 70
int y 72
int width 120
int height 10

section user14 // show toggle
int toggle 0
string fontname "arial"
int fontstyle 1
int halign align.center
list fontcolor color.alttext
string fspec "$if($and(%artist%,%title%),$ifgreater(%_istoggled%,0,show metadata,show file data),$if($or(%artist%,%title%),$ifgreater(%user19._istoggled%,0,show file data '(*)',show file data),$ifgreater(%user19._istoggled%,0,guessing all tags..,)))"
int x 74
int y 83
int width 110
int height 10

// mid section //

section songtime // current time
int toggle 0
string fontname "verdana"
int fontstyle 3
int fontsize 8
string fspec "$ifgreater(%_istoggled%,0,-%rt%,%et%)/"
int halign align.far
int x 187
int y 86
int width 80
int height 11

section title6 // track length
list fontcolor color.midgray
int fontsize 11
int fontstyle 3
string fspec %_length%
int y 73
string include songtime

section user18 // square button
int toggle 0
string tooltip "toggle id3 placeholders"
int show show.always // because user12 is on stop only
int x 8
int y 150
int srcx 280
int srcy 38
int width 6
int height 6
string include user12

section user19
int toggle 1
string include user18
string tooltip "toggle smart-tags '(guess missing fields)'"
int x 16

///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

section title8 // display artist
string fspec "%metaExtend._spacer% $if($or(%artist%,$strcmp(%user19._istoggled%,1)),$ifgreater(%user14._istoggled%,0,,%id3._neatArtist%),)"
int valign align.far
int y 102
int height 17
string include metaExtend

section title16 // placeholder 1
string fspec "$ifgreater(%user18._istoggled%,0,$ifgreater(%user14._istoggled%,0,,$ifgreater(%user19._istoggled%,0,artist:,$if(%artist%,artist:,))),)"
int y title8.y
int height title8.height
string include placeHolder

section title9 // display title
string fspec "%metaExtend._spacer% $if($or(%title%,$strcmp(%user19._istoggled%,1)),$ifgreater(%user14._istoggled%,0,%_filename_ext%,%id3._neatTitle%),%_filename_ext%)"
int valign align.center
int y 119
int height 12
string include metaExtend

section title17 // placeholder 2
string fspec "$ifgreater(%user18._istoggled%,0,$ifgreater(%user14._istoggled%,0,file:,$ifgreater(%user19._istoggled%,0,title:,$if(%title%,title:,file:))),)"
int y title9.y
int height title9.height
string include placeHolder

section title10 // display album
list fontcolor color.midgray
string fspec "%metaExtend._spacer% $if($or(%album%,$strcmp(%user19._istoggled%,1)),$ifgreater(%user14._istoggled%,0,/$directory(%_path%,1),%id3._neatAlbum%),/$directory(%_path%,1))"
int valign align.near
int y 131
int height 17
string include metaExtend

section title18 // placeholder 3
string fspec "$ifgreater(%user18._istoggled%,0,$ifgreater(%user14._istoggled%,0,folder:,$ifgreater(%user19._istoggled%,0,album:,$if(%album%,album:,folder:))),)"
list fontcolor title10.fontcolor
int y title10.y
int height title10.height
string include placeHolder


// bottom section //

section user13 // show mono/stereo
string fontname "tahoma"
int fontsize 6
int texthint 0
string fspec "%tech._stereo%"
int x 7
int y  164
int width 37
int height 9
string include tech

section title11 // show file type
int fontsize 10
list fontcolor color.lightgray
string fspec "%tech._fileType%"
int x 5
int y 171
int width 80	
int height 12
string include tech

section title12 // show Kbps/Khz
int fontsize 6
list fontcolor color.alttext
string fspec "$if2(%__bitrate%         %tech._rate%,N/A)"
int x 6
int y 183
int width 90 // 25
int height 8
string include tech

section title15 // kbps & khz placeholders
list fontcolor color.offwhite
string fspec "$select(%tech._bitsize%,  %tech._kbpkhz%,%tech._kbpkhz%,  %tech._kbpkhz%,    %tech._kbpkhz%)"
int x 18
int width 80
string include title12 // kbps

section title14 // show comments
string fontname "microsoft sans serif"
int texthint 0
int halign align.center
int textflags 0x00000000
list fontcolor color.lightgray
string fspec "$ifgreater(%user14._istoggled%,0,,$if2(%comment%,))"
int x 87
int y 161
int width 108	
int height 33
string include tech


//

section Spectrum
bool layers false
bool mouseinput false
int srcx 290
int srcy 84
int x 6
int y 85
int width 260
int height 107
int bands 20 // 26

section albumart
bool nolayers true
int command command.look_albumart_next
int command_rbu command.look_albumart_prev
int x 211
int y 136
int width 55
int height 55
string search1 "*front*"
string search2 "*cover*"
string search3 "*back*"
string search4 "*cd*"
string search5 "*"