section lookinfo
string name "the micropanel"
string author "tk32"
string date "Feb-02-2004"
double version 1.0
string description "any suggestions email: tkelly32@btinternet.com"
string URL "http://www.btinternet.com/~sean.m.kelly/foo_looks/"

import micropanel_common.ski
//import tk32_progBar_Mk1.ski


section presets
int startmode 2 	// 1 = playlist, 2 = id3, 3 = vis
int mini 1
int timedisplay 0 	// 0 = elapsed, 1 = remaining
string bgtext "tk32"



section globals
string image "micropanel.png"
list fontcolor color.darkblue
string fontname "Arial Black"
int fontsize 8
int layer 1
int halign align.near
list statemap states.None

section window
int width 244
int height 109

sprite background
int layer 0
list srcoff int { 26 14 }
int width window.width
int height window.height
list scripts string { "draglook" }

//
/// all big modes ///
//

// titlebar //
sprite foobarlogo
list rect int { 3 0 12 11 }
list srcoff int { 6 15 }
list scripts string { "openMenu[menu='foobar2000']" }
list statemap states.press

sprite makemini
int layer 100
list rect int { 219 2 9 9 }
list srcoff int { 144 164 }
list statemap int { 0 0 1 1 0 0 0 1 1 0 }
list rendermap int { render.image }
list scripts string { "makeMini[init=look_getValue('presets','mini')]" }

sprite closebutton
list rect int { 231 2 9 9 }
list srcoff int { 154 164 }
list statemap states.roll
list scripts string { "[function onleftbuttonup(this) fb2k_menuCommand('Foobar2000/Exit') end]", "[function onrightbuttonup(this) look_hide() end]"  }

// tabs //
section tabs
list rect int { 0 84 19 10 }
list srcoff int { 0 161 }
list statemap states.presstogg

sprite pltab
string include tabs
int x 158
int srcX 166
list scripts string { "[function onrightbuttonup(this) fb2k_menuCommand('Foobar2000/Activate main window') end]", "switchMode[i=1 init=look_getValue('presets','startmode')]" }

sprite id3tab
string include tabs
int x 175
int srcX 183
list scripts string { "[function onrightbuttonup(this) fb2k_playlistContextCommand('Show file info') end]", "switchMode[i=2]" }

sprite vistab
string include tabs
int x 196
int srcX 204
list scripts string { "[function onrightbuttonup(this) enable(skininfo) end]", "switchMode[i=3]" }

// menus //
section menu
list rect int { 0 2 0 9 }
list srcoff int { 0 131 }
int fontsize 6
list fontcolor int { 255 150 150 150 }
list rendermap int { render.image }
list statemap states.rollpress1

sprite playbackmenu
string include menu
int x 18
int width 31
int srcX 185
string fspec "Control"
list scripts string { "openMenu[menu='playback']" }

sprite playlistmenu
string include menu
int x 50
int width 10
int srcX 216
string fspec "PL"
list scripts string { "openMenu[menu='playlist']" }

sprite componentsmenu
string include menu
int x 62
int width 51
int srcX 226
string fspec "Components"
list scripts string { "openMenu[menu='components']" }

/// buttons ///
section playback
list rect int { 0 89 20 16 }
list srcoff int { 0 133 }
list statemap states.press

sprite prevbutton
string include playback
int x 5
int srcX 20
list scripts string { "playback[type='prev']" }

sprite playbutton
string include playback
int x 27
int srcX 42
list scripts string { "playback[type='playpause']" }

sprite stopbutton
string include playback
int x 49
int srcX 64
list scripts string { "playback[type='stop']" }

sprite nextbutton
string include playback
int x 71
int srcX 86
list scripts string { "playback[type='next']" }

// misc //
sprite leftMask
int layer 1
list rect int { 0 13 16 72 }
list srcoff int { 254 228 }

sprite rightMask
int layer 1
list rect int { 223 13 21 72 }
list srcoff int { 279 228 }

sprite skininfo
bool visible false
bool enabled false
int layer 3
list rect int { 18 20 203 59 }
list srcoff int { 7 202 }
list scripts string { "[function onleftbuttonup(this) disable(this) end]" }

sprite showConsole
list rect int { 222 88 10 10 }
list fontcolor int { 255 150 150 150 }
string fspec "c"
list rendermap int { render.text }
list scripts string { "[function onleftbuttonup(this) fb2k_menuCommand('Components/Show console') end]", "blackOnRoll" }

sprite bignumber
bool enabled false
list rect int { 7 17 224 43 }
int layer 0
int fontsize 50
int halign align.far
list fontcolor int { 40 170 170 200 }
list fillcolor int { 150 150 150 0 }
string fspec presets.bgtext
list rendermap int { render.text }

sprite titlebar
int layer 0
list rect int { 0 0 230 12 }
list fillcolor int { 150 40 40 150 }
list rendermap int { }
list scripts string {"doubleMini", "draglook"}



//
/// playlist mode only //
//

// playlist //
section ple_common
int fontsize 6
list fontcolor color.black
list rect int { 8 0 210 11 }
list bordercolor color.ghostblue
int borderwidth 0
list rendermap int { render.fill, render.Border, render.Text }
string fspec tagz.plEntry
list scripts string { "playlistControl" }

sprite ple_1
int y 17
string include ple_common

sprite ple_2
int y 28
string include ple_1

sprite ple_3
int y 39
string include ple_1

sprite ple_4
int y 50
string include ple_1

sprite ple_5
int y 61
string include ple_1

sprite ple_6
int y 72
string include ple_1

sprite nowPlaying
list scripts string { "playlist" }


// playlist buttons & indicators //
sprite playlistUp
list rect int {220 20 8 28}
list srcoff int { 230 203 }
list scripts string { "playlistScrollBtn[dir=-1]" }
list statemap states.presstogg

sprite playlistDown
string include playlistUp
int y 52
int srcX 240
list scripts string { "playlistScrollBtn[dir=1]" }

sprite jumpcurrent
list rect int { 89 87 60 10 }
int fontsize 6
int halign align.far
list fontcolor int { 200 100 100 100 }
list rendermap int { render.text }
string text "current"
list scripts string { "[function onleftbuttonup(this)  look_callScript(nowPlaying,'scrollTo',fb2k_getNowPlaying()) end]",
"[function onleftbuttondoubleclick(this) look_callScript(nowPlaying,'scrollTo',fb2k_getNowPlaying()) fb2k_playlistSetFocusSel(fb2k_getNowPlaying()) end ]" }

sprite jumpfocus
string include jumpcurrent
int y 95
string text "focus"
list scripts string { "[function onleftbuttonup(this)  look_callScript(nowPlaying,'scrollTo',fb2k_playlistGetFocus()) end]",
"[function onleftbuttondoubleclick(this)  look_callScript(nowPlaying,'scrollTo',fb2k_playlistGetFocus()) fb2k_playlistPlay(fb2k_playlistGetFocus()) end]" }




//
/// id3 mode only ///
//

///// track info /////
section trackinfo
int layer 0
int halign align.far
list rect int { 8 0 218 15 }
list rendermap int { render.text }

sprite artist
string include trackinfo
int fontsize 9
int y 28
string fspec "$replace(%artist%,Various Artists,VA,  , )"
list scripts string { "[function onleftbuttondoubleclick(this) fb2k_playlistContextCommand('Show file info') end]", "textscroll" }

sprite title
string include trackinfo
int fontstyle 2
int y 43
string fspec tagz.title
list scripts artist.scripts

sprite songtime
string include trackinfo
list rect int { 103 61 121 20 }
int halign align.far
list fontcolor color.ghostblue
int fontsize 14
string fspec "$ifgreater(%_istoggled%,0,-%rtm%,%etm%)"
list scripts string { "toggle[init=look_getValue('presets','timedisplay')]" }

sprite songtime2
string include songtime
list fontcolor color.ghostwhite
int x 104
int y 62

// progress //
sprite progBar
int layer 5
list rect int { 10 60 0 22 }
list rendermap int { render.fill }
list fillcolor color.ghostgray
list fillcolor2 color.ghostlightgray

//sprite progGrip
//list rect int { 10 60 38 22 }
//list srcoff int { 12 217 }

sprite progBox
string include progBar
int width 216
list rendermap int { render.border }
int borderwidth 1
list bordercolor color.ghostgray
list scripts string { "dragBar[bar=progBar]" }
//list scripts string { "tk32_progBar[bar=progBar grip=progGrip]" }




//
/// vis mode only //
//

// progress //
sprite progBar2
string include progBar
list rect int { 8 18 0 10 }
list fillcolor int { 15 0 0 255 }
list fillcolor2 color.ghostblue

sprite progBox2
string include progBar2
int width 219
list rendermap int { render.border }
int borderwidth 1
list bordercolor int { 255 150 150 150 }
list scripts string { "dragBar[bar=progBar2]" }

/// spectrum ////
sprite spectrum
list rect int { 9 42 220 40 }
list srcoff int { 290 85 }
int bands 20
list rendermap int {}
list scripts string { "spectrumAnim" }

// text //
sprite visText
int layer 0
list rect int { 10 30 216 12 }
int halign align.far
string fspec tagz.visText
list rendermap int { render.text }
list scripts string { "textscroll" }




//
/// mini mode only
//

// mini buttons //
section miniplayback
list rect int { 0 98 11 7 }
list srcoff int { 0 160 }
list statemap states.rollpress

sprite miniprev
string include miniplayback
int x 154
int srcX 232
list scripts prevbutton.scripts

sprite miniplay
string include miniplayback
int x 166
int srcX 244
list scripts playbutton.scripts

sprite ministop
string include miniplayback
int x 178
int width 7
int srcX 256
list scripts stopbutton.scripts

sprite mininext
string include miniplayback
int x 187
int srcX 264
list scripts nextbutton.scripts

// text //
sprite miniText
list rect int { 7 16 195 12 }
int fontsize 6
string fspec tagz.miniText
list rendermap int { render.text} 

sprite miniTime
string include miniText
int halign align.far
list rect int { 198 16 30 12 }
string fspec "$ifgreater(%_istoggled%,0,-%rtm%,%etm%)"
list scripts string { "toggle[init=look_getValue('presets','timedisplay')]" }